ASP的Base64加密解密函数 - 个人学习记录

这个业务逻辑多少都有点奇怪了，阅读浏览次数增值在新闻详情页的控制器方法里setInc，这怎么还写进模型事件里了。如果非要用onAfterRead也可以，把新闻文章的内容单独分出来一个news_content表，然后把它和news做关联，然后给news_content表的onAfterRead事件做增值处理，这样点进新闻页内查询到文章内容时才会触发它。: 评 TP6模型事件-查询后onAfterRead不好用

文章标签更多

ThinkPHP (260)

Mysql (59)

DedeCms (33)

jQuery (74)

证件照 (1)

尺寸大小 (2)

背景颜色 (1)

setInc (4)

setDec (4)

onclick (5)

友情链接更多

超纯水设备

免费设计

海报设计

快递查询

加密解密 Base64

打开边栏(ESC) 关闭边栏(ESC)

100

101

<%
OPTION EXPLICIT
const BASE_64_MAP_INIT = "ABCDEFGHIJKLMNOPQRSTUVWXYZabcdefghijklmnopqrstuvwxyz0123456789+/"
dim newline
dim Base64EncMap(63)
dim Base64DecMap(127)
'初始化函数
PUBLIC SUB initCodecs()
    ' 初始化变量
    newline = "<P>" & chr(13) & chr(10)
    dim max, idx
    max = len(BASE_64_MAP_INIT)
    for idx = 0 to max - 1
        Base64EncMap(idx) = mid(BASE_64_MAP_INIT, idx + 1, 1)
    next
    for idx = 0 to max - 1
        Base64DecMap(ASC(Base64EncMap(idx))) = idx
    next
END SUB
'Base64加密函数
PUBLIC FUNCTION base64Encode(plain)
    if len(plain) = 0 then
        base64Encode = ""
        exit function
    end if
    dim ret, ndx, by3, first, second, third
    by3 = (len(plain) \ 3) * 3
    ndx = 1
    do while ndx <= by3
        first = asc(mid(plain, ndx+0, 1))
        second = asc(mid(plain, ndx+1, 1))
        third = asc(mid(plain, ndx+2, 1))
        ret = ret & Base64EncMap( (first \ 4) AND 63 )
        ret = ret & Base64EncMap( ((first * 16) AND 48) + ((second \ 16) AND 15 ) )
        ret = ret & Base64EncMap( ((second * 4) AND 60) + ((third \ 64) AND 3 ) )
        ret = ret & Base64EncMap( third AND 63)
        ndx = ndx + 3
    loop
    if by3 < len(plain) then
        first = asc(mid(plain, ndx+0, 1))
        ret = ret & Base64EncMap( (first \ 4) AND 63 )
        if (len(plain) MOD 3 ) = 2 then
            second = asc(mid(plain, ndx+1, 1))
            ret = ret & Base64EncMap( ((first * 16) AND 48) + ((second \ 16) AND 15 ) )
            ret = ret & Base64EncMap( ((second * 4) AND 60) )
        else
            ret = ret & Base64EncMap( (first * 16) AND 48)
            ret = ret '& "="
        end if
        ret = ret '& "="
    end if
    base64Encode = ret
END FUNCTION
'Base64解密函数
PUBLIC FUNCTION base64Decode(scrambled)
    if len(scrambled) = 0 then
        base64Decode = ""
        exit function
    end if
    dim realLen
    realLen = len(scrambled)
    do while mid(scrambled, realLen, 1) = "="
        realLen = realLen - 1
    loop
    dim ret, ndx, by4, first, second, third, fourth
    ret = ""
    by4 = (realLen \ 4) * 4
    ndx = 1
    do while ndx <= by4
        first = Base64DecMap(asc(mid(scrambled, ndx+0, 1)))
        second = Base64DecMap(asc(mid(scrambled, ndx+1, 1)))
        third = Base64DecMap(asc(mid(scrambled, ndx+2, 1)))
        fourth = Base64DecMap(asc(mid(scrambled, ndx+3, 1)))
        ret = ret & chr( ((first * 4) AND 255) + ((second \ 16) AND 3))
        ret = ret & chr( ((second * 16) AND 255) + ((third \ 4) AND 15))
        ret = ret & chr( ((third * 64) AND 255) + (fourth AND 63))
        ndx = ndx + 4
    loop
    if ndx < realLen then
        first = Base64DecMap(asc(mid(scrambled, ndx+0, 1)))
        second = Base64DecMap(asc(mid(scrambled, ndx+1, 1)))
        ret = ret & chr( ((first * 4) AND 255) + ((second \ 16) AND 3))
        if realLen MOD 4 = 3 then
            third = Base64DecMap(asc(mid(scrambled,ndx+2,1)))
            ret = ret & chr( ((second * 16) AND 255) + ((third \ 4) AND 15))
        end if
    end if
    base64Decode = ret
END FUNCTION
 
' 初始化
call initCodecs
' 测试代码
dim inp, encode
inp = "mars20100220"
encode = base64Encode(inp)
'encode = "bWFyczIwMTAwMjIw0"
response.write "加密前为:" & inp & newline
response.write "加密后为:" & encode & newline
response.write "解密后为:" & base64Decode(encode) & newline
%>

赏

前一篇

asp检索一个文件夹中的文件，按修改日期为条件移动到另一个文...

后一篇

“最难不过坚持”

本人承接扒站仿站，php网站维护，病毒查杀，网站编辑，网站改版，html制作

asp检索一个文件夹中的文件，按修改日期为条件移动到另一个文...

asp实现跳出for循环，执行下一循环